Завершить загрузку частями

Подтверждает окончание загрузки объекта по частям

Параметры
Расширенный вызов ?

Функция ЗавершитьЗагрузкуЧастями(Знач Наименование, Знач Бакет, Знач ОсновныеДанные, Знач IDЗагрузки, Знач МассивТегов, Знач Заголовки = Неопределено, Знач Каталог = Ложь) Экспорт

Параметр	CLI опция	Тип	Обяз.	Назначение
Наименование	--name	Строка	✔	Наименование объекта в бакете
Бакет	--bucket	Строка	✔	Имя бакета для загрузки объекта
ОсновныеДанные	--basic	Структура Из КлючИЗначение	✔	Основные данные запроса. См. `ПолучитьСтруктуруДанных`
IDЗагрузки	--upload	Строка	✔	ID загрузки по частям. См. `ИнициализироватьЗагрузкуЧастями`
МассивТегов	--tags	Массив Из Строка	✔	Массив тегов (Etag) из загрузок каждой части
Заголовки	--headers	Соответствие Из КлючИЗначение	✖	Дополнительные заголовки запроса, если необходимо
Каталог	--dir	Булево	✖	Истина > Path style URL, Ложь > Virtual hosted style URL

Возвращаемое значение

Структура Из КлючИЗначение - сериализованный JSON ответа от хранилища

Параметр	Описание
proxy	`ИнтернетПрокси` или структура полей `Протокол`, `Сервер`, `Порт`, `Пользователь`, `Пароль`, `ИспользоватьАутентификациюОС`
timeout	Таймаут выполнения запроса
adv_response	Оформляет ответ в виде полной структуры HTTP-ответа с полями `code`, `body` и `headers`
retries	Число попыток отправки HTTP-запроса при коде `5**` или внутренних ошибках клиента
dontwait	Создает фоновое задание и возвращает его данные (только для 1С и OneScript)

подсказка

Метод в документации AWS: CompleteMultipartUpload

Это служебный метод. Для простого сценария загрузки файлов предназначен единый метод ЗагрузитьОбъект

Пример использования для 1С:Предприятие/OneScript
    URL       = "s3.openintegrations.dev";
    AccessKey = "bayselo...";
    SecretKey = "12we34...";
    Region    = "BTC";

    ОсновныеДанные = OPI_S3.ПолучитьСтруктуруДанных(URL, AccessKey, SecretKey, Region);

    Наименование = "fileChunked.mp3";

    Каталог = Истина; // Формирование URL в path-style
    Бакет = "w567hjy1";
    Содержимое = "https://hut.openintegrations.dev/test_data/song.mp3"; // URL, Путь или Двоичные данные
    Содержимое = OPI_ЗапросыHTTP.Get(Содержимое);

    Результат = OPI_S3.ИнициализироватьЗагрузкуЧастями(Наименование, Бакет, ОсновныеДанные, , Каталог);

    IDЗагрузки    = Результат["response"]["InitiateMultipartUploadResult"]["UploadId"];
    ОбщийРазмер   = Содержимое.Размер();
    РазмерУчастка = 5242880;
    ПрочитаноБайт = 0;
    НомерЧасти    = 1;

    ЧтениеДанных  = Новый ЧтениеДанных(Содержимое);
    ИсходныйПоток = ЧтениеДанных.ИсходныйПоток();
    МассивТегов   = Новый Массив;

    Пока ПрочитаноБайт < ОбщийРазмер Цикл

        ТекущееЧтение = ЧтениеДанных.Прочитать(РазмерУчастка);
        ТекущиеДанные = ТекущееЧтение.ПолучитьДвоичныеДанные();

        Если ТекущиеДанные.Размер() = 0 Тогда
            Прервать;
        КонецЕсли;

        Результат = OPI_S3.ЗагрузитьЧастьОбъекта(Наименование
            , Бакет
            , ОсновныеДанные
            , IDЗагрузки
            , НомерЧасти
            , ТекущиеДанные
            , Каталог);

        ПрочитаноБайт = ИсходныйПоток.ТекущаяПозиция();

        ETag = Результат["headers"]["Etag"];
        ETag = ?(ETag = Неопределено, Результат["headers"]["ETag"], ETag);

        МассивТегов.Добавить(ETag);

        НомерЧасти = НомерЧасти + 1;

    КонецЦикла;

    Результат = OPI_S3.ЗавершитьЗагрузкуЧастями(Наименование, Бакет, ОсновныеДанные, IDЗагрузки, МассивТегов, , Каталог);
    // ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

Bash
CMD/Bat

    # JSON данные также могут быть переданы как путь к файлу .json
    
    oint s3 ЗавершитьЗагрузкуЧастями \
      --name "fileChunked.mp3" \
      --bucket "4c81a26b" \
      --basic "{'URL':'s3.openintegrations.dev','AccessKey':'***','SecretKey':'***','Region':'BTC','Service':'s3'}" \
      --upload "MGI2Y2U2YTAtMDYxZC00NzkwLTk3YmEtOTM0NDY2MWFjZGYwLjFhNzQwYjE3LTk5NGUtNDMzZS05Mjk3LWRkYTA1OGVjYmYzNXgxNzgxODEwMDE1NjY4Mzc4NTU4" \
      --tags "['\"'"566e2d464b39b91eb8b5d89fb9f1a318\"'"','\"'"adb76a9a9ff8226ed08fb6f343102908\"'"']" \
      --dir true

    :: JSON данные также могут быть переданы как путь к файлу .json
    
    oint s3 ЗавершитьЗагрузкуЧастями ^
      --name "fileChunked.mp3" ^
      --bucket "4c81a26b" ^
      --basic "{'URL':'s3.openintegrations.dev','AccessKey':'***','SecretKey':'***','Region':'BTC','Service':'s3'}" ^
      --upload "MGI2Y2U2YTAtMDYxZC00NzkwLTk3YmEtOTM0NDY2MWFjZGYwLjFhNzQwYjE3LTk5NGUtNDMzZS05Mjk3LWRkYTA1OGVjYmYzNXgxNzgxODEwMDE1NjY4Mzc4NTU4" ^
      --tags "['\"'"566e2d464b39b91eb8b5d89fb9f1a318\"'"','\"'"adb76a9a9ff8226ed08fb6f343102908\"'"']" ^
      --dir true

Результат
{
 "status": 200,
 "response": {
  "CompleteMultipartUploadResult": {
   "Location": "http://s3.openintegrations.dev/97a02c78/fileChunked.mp3",
   "Bucket": "97a02c78",
   "Key": "***",
   "ETag": "\"22c09aeeb42144b375de8a4c1a1bb573-2\""
  }
 },
 "headers": {
  "Accept-Ranges": "bytes",
  "ETag": "\"22c09aeeb42144b375de8a4c1a1bb573-2\"",
  "Vary": "Accept-Encoding",
  "Server": "Microsoft-IIS/10.0",
  "Strict-Transport-Security": "max-age=31536000; includeSubDomains",
  "X-Amz-Id-2": "dd9025bab4ad464b049177c95eb6ebf374d3b3fd1af9251148b658df7ac2e3e8",
  "X-Amz-Request-Id": "18BA402AF50F908E",
  "X-Content-Type-Options": "nosniff",
  "X-Ratelimit-Limit": "6209",
  "X-Ratelimit-Remaining": "6209",
  "X-XSS-Protection": "1; mode=block",
  "X-Powered-By": "ARR/3.0",
  "Date": "Thu, 18 Jun 2026 18:25:55 GMT",
  "Content-Type": "application/xml",
  "Content-Length": "334"
 }
}