Выполнить запрос SQL

Выполняет произвольный SQL запрос

Функция ВыполнитьЗапросSQL(Знач ТекстЗапроса, Знач Параметры = "", Знач ФорсироватьРезультат = Ложь, Знач Соединение = "", Знач Tls = "") Экспорт

Параметр	CLI опция	Тип	Обяз.	Назначение
ТекстЗапроса	--sql	Строка	✔	Текст запроса к базе
Параметры	--params	Массив Из Произвольный	✖	Массив позиционных параметров запроса
ФорсироватьРезультат	--force	Булево	✖	Включает попытку получения результата, даже для не SELECT запросов
Соединение	--dbc	Строка, Произвольный	✖	Соединение или строка подключения
Tls	--tls	Структура Из КлючИЗначение	✖	Настройки TLS, если необходимо. См. ПолучитьНастройкиTls

Возвращаемое значение: Соответствие Из КлючИЗначение - Результат выполнения запроса

подсказка

Параметры запроса указываются как массив структур вида {'Тип данных': 'Значение'}. Список доступных типов описан на начальной странице документации библиотеки MSSQL

Без указания флага ФорсироватьРезультат, чтение результата осуществляется только для запросов, начинающихся с SELECT Для остальных запросов возвращается result:true или false с текстом ошибки

Пример использования для 1С:Предприятие/OneScript

    ТекущаяДата = OPI_Инструменты.ПолучитьТекущуюДату();
    Картинка    = "https://hut.openintegrations.dev/test_data/picture.jpg";
    OPI_ПреобразованиеТипов.ПолучитьДвоичныеДанные(Картинка); // Картинка - Тип: ДвоичныеДанные

    Адрес  = "127.0.0.1";
    Логин  = "SA";
    Пароль = "12we...";
    База   = "test_data";

    НастройкиTLS      = OPI_MSSQL.ПолучитьНастройкиTLS(Истина);
    СтрокаПодключения = OPI_MSSQL.СформироватьСтрокуПодключения(Адрес, База, Логин, Пароль);
    Соединение        = OPI_MSSQL.ОткрытьСоединение(СтрокаПодключения, НастройкиTLS);

    // CREATE

    ТекстЗапроса = "
        |CREATE TABLE test_table (
        |    ID INT PRIMARY KEY,
        |    FirstName NVARCHAR(50),
        |    LastName NVARCHAR(50),
        |    BirthDate DATE,
        |    IsEmployed BIT,
        |    Salary DECIMAL(10, 2),
        |    CreatedAt DATETIME,
        |    Age SMALLINT,
        |    RowGuid UNIQUEIDENTIFIER,
        |    Data VARBINARY(MAX)
        |);";

    Результат = OPI_MSSQL.ВыполнитьЗапросSQL(ТекстЗапроса, , , Соединение);

    // INSERT с параметрами

    ТекстЗапроса = "
        |INSERT INTO test_table (ID, FirstName, LastName, BirthDate, IsEmployed, Salary, CreatedAt, Age, RowGuid, Data)
        |VALUES (@P1, @P2, @P3, @P4, @P5, @P6, @P7, @P8, @P9, @P10);";

    МассивПараметров = Новый Массив;
    МассивПараметров.Добавить(Новый Структура("INT"     , 1));
    МассивПараметров.Добавить(Новый Структура("NVARCHAR", "Vitaly"));
    МассивПараметров.Добавить(Новый Структура("NVARCHAR", "Alpaca"));
    МассивПараметров.Добавить(Новый Структура("DATE"    , ТекущаяДата));
    МассивПараметров.Добавить(Новый Структура("BIT"     , Истина));
    МассивПараметров.Добавить(Новый Структура("DECIMAL" , 10.30));
    МассивПараметров.Добавить(Новый Структура("DATETIME", ТекущаяДата));
    МассивПараметров.Добавить(Новый Структура("SMALLINT", 20));
    МассивПараметров.Добавить(Новый Структура("UUID"    , Новый УникальныйИдентификатор));
    МассивПараметров.Добавить(Новый Структура("BYTES"   , Картинка));

    Результат = OPI_MSSQL.ВыполнитьЗапросSQL(ТекстЗапроса, МассивПараметров, , Соединение);

    // SELECT (Результат этого запроса приведен в следующем блоке)

    ТекстЗапроса = "SELECT FirstName, LastName, BirthDate, IsEmployed, Salary, CreatedAt, Age, RowGuid, Data FROM test_table;";

    Результат = OPI_MSSQL.ВыполнитьЗапросSQL(ТекстЗапроса, , , Соединение);

    // SQL запрос из файла

    ФайлSQL = "https://hut.openintegrations.dev/test_data/TEST_DATA2.sql"; // Двоичные данные, URL или путь к файлу

    Результат = OPI_MSSQL.ВыполнитьЗапросSQL(ФайлSQL, , , Соединение);

    Закрытие = OPI_MSSQL.ЗакрытьСоединение(Соединение);

Bash

    # JSON данные также могут быть переданы как путь к файлу .json
    
    oint mssql ВыполнитьЗапросSQL \
      --sql "https://hut.openintegrations.dev/test_data/TEST_DATA2.sql" \
      --dbc "Server=127.0.0.1;Database=***;User Id=SA;Password=***;" \
      --tls "{'use_tls':true,'accept_invalid_certs':true,'ca_cert_path':''}"

CMD/Bat

    :: JSON данные также могут быть переданы как путь к файлу .json
    
    oint mssql ВыполнитьЗапросSQL ^
      --sql "https://hut.openintegrations.dev/test_data/TEST_DATA2.sql" ^
      --dbc "Server=127.0.0.1;Database=***;User Id=SA;Password=***;" ^
      --tls "{'use_tls':true,'accept_invalid_certs':true,'ca_cert_path':''}"

Результат

{
 "data": [
  {
   "Age": 20,
   "BirthDate": "2025-10-14",
   "CreatedAt": "2025-10-14T16:47:48",
   "Data": {
    "BYTES": "Base64"
   },
   "FirstName": "Vitaly",
   "IsEmployed": 1,
   "LastName": "Alpaca",
   "RowGuid": "900ff981-d65a-4f78-84e9-17e77ef6ea5b",
   "Salary": 10.3
  }
 ],
 "result": true
}