Выполнить запрос SQL

Выполняет произвольный SQL запрос

Функция ВыполнитьЗапросSQL(Знач ТекстЗапроса, Знач Параметры = "", Знач ФорсироватьРезультат = Ложь, Знач Соединение = "", Знач Tls = "") Экспорт

Параметр	CLI опция	Тип	Обяз.	Назначение
ТекстЗапроса	--sql	Строка	✔	Текст запроса к базе
Параметры	--params	Массив Из Произвольный	✖	Массив позиционных параметров запроса
ФорсироватьРезультат	--force	Булево	✖	Включает попытку получения результата, даже для не SELECT запросов
Соединение	--dbc	Строка, Произвольный	✖	Соединение или строка подключения
Tls	--tls	Структура Из КлючИЗначение	✖	Настройки TLS, если необходимо. См. ПолучитьНастройкиTls

Возвращаемое значение: Соответствие Из КлючИЗначение - Результат выполнения запроса

подсказка

Параметры запроса указываются как массив структур вида {'Тип данных': 'Значение'}. Список доступных типов описан на начальной странице документации библиотеки PostgreSQL

Без указания флага ФорсироватьРезультат, чтение результата осуществляется только для запросов, начинающихся с SELECT Для остальных запросов возвращается result:true или false с текстом ошибки

Пример использования для 1С:Предприятие/OneScript

    Картинка = "https://api.athenaeum.digital/test_data/picture.jpg";
    OPI_ПреобразованиеТипов.ПолучитьДвоичныеДанные(Картинка); // Картинка - Тип: ДвоичныеДанные

    Адрес  = "127.0.0.1";
    Логин  = "bayselonarrend";
    Пароль = "12we...";
    База   = "test_data";

    СтрокаПодключения = OPI_PostgreSQL.СформироватьСтрокуПодключения(Адрес, База, Логин, Пароль);
    Соединение        = OPI_PostgreSQL.ОткрытьСоединение(СтрокаПодключения);

    // CREATE

    ТекстЗапроса = "
                   |CREATE TABLE test_table (
                   |id SERIAL PRIMARY KEY,
                   |name NAME,
                   |age INT,
                   |salary REAL,
                   |is_active BOOL,
                   |created_at DATE,
                   |data BYTEA
                   |);";

    Результат = OPI_PostgreSQL.ВыполнитьЗапросSQL(ТекстЗапроса, , , Соединение);

    // INSERT с параметрами

    ТекстЗапроса = "
                   |INSERT INTO test_table (name, age, salary, is_active, created_at, data)
                   |VALUES ($1, $2, $3, $4, $5, $6);";

    МассивПараметров = Новый Массив;
    МассивПараметров.Добавить(Новый Структура("NAME" , "Vitaly"));
    МассивПараметров.Добавить(Новый Структура("INT"  , 25));
    МассивПараметров.Добавить(Новый Структура("REAL" , 1000.12));
    МассивПараметров.Добавить(Новый Структура("BOOL" , Истина));
    МассивПараметров.Добавить(Новый Структура("DATE" , OPI_Инструменты.ПолучитьТекущуюДату()));
    МассивПараметров.Добавить(Новый Структура("BYTEA", Картинка));

    Результат = OPI_PostgreSQL.ВыполнитьЗапросSQL(ТекстЗапроса, МассивПараметров, , Соединение);

    // SELECT (Результат этого запроса приведен в следующем блоке)

    ТекстЗапроса = "SELECT id, name, age, salary, is_active, created_at, data FROM test_table;";

    Результат = OPI_PostgreSQL.ВыполнитьЗапросSQL(ТекстЗапроса, , , Соединение);

    // DO + Транзакция

    ТекстЗапроса = "DO $$
                   |BEGIN
                   |    CREATE TABLE users (
                   |        id SMALLSERIAL,
                   |        name TEXT NOT NULL,
                   |        age INT NOT NULL
                   |    );
                   |    INSERT INTO users (name, age) VALUES ('Alice', 30);
                   |    INSERT INTO users (name, age) VALUES ('Bob', 25);
                   |    INSERT INTO users (name, age) VALUES ('Charlie', 35);
                   |    COMMIT;
                   |END $$ LANGUAGE plpgsql;";

    Результат = OPI_PostgreSQL.ВыполнитьЗапросSQL(ТекстЗапроса, , , Соединение);

    // SQL запрос из файла

    ФайлSQL = "https://api.athenaeum.digital/test_data/TEST_DATA.sql"; // Двоичные данные, URL или путь к файлу

    Результат = OPI_PostgreSQL.ВыполнитьЗапросSQL(ФайлSQL, , , Соединение);

    Закрытие = OPI_PostgreSQL.ЗакрытьСоединение(Соединение);

Bash

    oint postgres ВыполнитьЗапросSQL \
      --sql "https://github.com/Bayselonarrend/OpenIntegrations/raw/main/service/test_data/TEST_DATA.sql" \
      --dbc "postgresql://bayselonarrend:***@127.0.0.1:5432/"

CMD/Bat

    oint postgres ВыполнитьЗапросSQL ^
      --sql "https://github.com/Bayselonarrend/OpenIntegrations/raw/main/service/test_data/TEST_DATA.sql" ^
      --dbc "postgresql://bayselonarrend:***@127.0.0.1:5432/"

Результат

{
 "data": [
  {
   "age": 25,
   "created_at": "2025-02-14",
   "data": {
    "BYTEA": "Base64"
   },
   "id": 1,
   "is_active": true,
   "name": "Vitaly",
   "salary": 1000.11999511719
  }
 ],
 "result": true
}